; 6/18/05 CFGE - set Config Entry at 70/71, clears location 72.
; When run from 70 puts SR bits 0-5 in loc 355 (TTY slot)
; and runs from 2. If SR bits 6-11 are clear and SR bit 15 set,
; then puts 177777 in SR before running from 2 to disable autostarting.
; If SR bits 6-11 contain non-zero then right-shifted by 6 and
; copied to location 271 to set the BACI slot. SR settings are
; saved to location 72 to serve as a trigger, after setting the
; slot locations and stuff hpiplos is run from 2.
;
"Loading CFGE" $PRINT CRLF
OCTAL CREATE CFGE
 LDA CFGJ
 STA 70
 LDA CFGA
 STA 71
 CLA
 STA 72
 JMP END
CFTM OCT 000077             mask for TTY bits in SR
CFBM OCT 007700             mask for BACI bits in SR
CFDA OCT 177777             SR code to disable autostart
CFGJ JMP 71,I               instruction put in loc 70
CFGA DEF *+1                address put in loc 71
 LIA 1                      get SR settings
 STA 72                     save settings in location 72
 AND CFTM                   keep only bits 0-5
 STA 355                    put in TTY slot location
 LIA 1                      get SR settings again
 AND CFBM                   keep only bits 6-11
 SZA                        skip if zero (no baci specified)
 JMP CFSB                   jump to set baci slot if value
 LIA 1                      get SR settings again
 SSA,RSS                    skip if bit 15 set
 JMP 2                      start hpiplos if clear
 LDA CFDA                   get disable-autostart setting
 OTA 1                      write to switches
 JMP 2                      and start hpiplos
CFSB CLB                    set baci slot... clear B reg
 LSR 6                      right-shift 6 places
 STA 271                    save in BACI slot location
 JMP 2                      start hpiplos
END
;
CFGE ;run it to make sure alt entry jmp is in place and 72 clear
;
CONSOLE