* Boot 7900 drive 1.. load bootext from blocks 0-5 and JSB 2055,I to run it
* Switches... bit 0 set for removeable, clear for fixed platter
* bits 3-4 set to "01" to tell 7900 bext to load from drive 1 (for bext)
* bits 6-11 set to slot number (for bext)
* hard-coded to slots 11/12 drive 1, start from location 77500
* 2/22/07 WTN
       ORG 77500B
DC     EQU 11B
CC     EQU 12B
* seek to sector 0
       CLC DC
       CLC CC
       CLA
       OTA DC               set cylinder = 0  
       STC DC,C             output to data channel
       LDA SKCMD            get seek command
       OTA CC               output to command channel
       STC CC,C             initiate seek
       SFS DC               first address word accepted?
       JMP *-1              no, wait
       CLA                  start head/sect = 0
       LIB 1
*      SLB,RSS              skip if SR bit 0 set
       OCT 6011             hpasm bug
       IOR RMBIT            if SR bit 0 clear, then fixed boot
       OTA DC
       STC DC,C             output to data channel
       SFS CC               seek complete?
       JMP *-1              no, wait
* load bootext from disk...
       CLC DC               clear control on data
       CLC CC                and command channels
       LDA CW1              get dma control word 1
       OTA 6                send to dma channel
       CLC 2                prepare for cw2
       LDA CW2              get cw2, address
       OTA 2                send to dma channel
       STC 2                prepare for cw3
       LDA CW3              get cw3, -length
       OTA 2                send to dma channel
       LDA RDCMD            get read command
       OTA CC               send to disk command channel
       STC DC,C             prepare data channel for read
       STC 6,C              activate dma
       STC CC,C             activate read
       SFS CC               done?
       JMP *-1              no, wait
* run bootext and boot
       JSB ENTRY,I
RMBIT  OCT 001000           bit 9 set for head 2
RDCMD  OCT 020001           read command
SKCMD  OCT 030001           seek command
CW1    OCT 120011           dma cw1 for read, note slot 11
CW2    OCT 102011           dma cw2, read into 2011
CW3    OCT 164000           dma cw3, inverse length (-6144)
ENTRY  OCT 102055           entry point, 2055 indirect