100  REM ** HAMURABI - GOVERN THE KINGDOM OF SUMERIA
110  REM ** MODIFIED BY PEOPLE'S COMPUTER COMPANY
120  REM ** VARIABLES USED IN THE PROGRAM
130  REM      A1 => POPULATION
140  REM      A2 => IMMIGRANTS LAST YEAR
150  REM      A3 => DEATHS LAST YEAR
160  REM      B1 => BUSHELS IN STOREHOUSES
170  REM      B2 => BUSHELS DESTROYED LAST YEAR BY RATS
180  REM      B3 => HARVEST PER ACRE LAST YEAR
190  REM      B4 => TOTAL HARVEST LAST YEAR
200  REM      C1 => ACRES OWNED BY CITY
210  REM      C2 => VALUE OF AN ACRE
220  REM      I  => TEMPORARY VARIABLE
230  REM      J  =>     "        "
300  REM ** INITIALIZATION
310  PRINT "HAMURABI - ";
320  PRINT "WHERE YOU GOVERN THE ANCIENT KINGDOM OF SUMERIA."
330  PRINT "THE OBJECT IS TO FIGURE OUT HOW THE GAME WORKS!"'7"!"'7
340  PRINT "(IF YOU WANT TO QUIT, SELL ALL YOUR LAND.)"
350  PRINT 
400  A1=100
410  A2=5
420  A3=0
430  B1=2800
440  B2=200
450  B3=3
460  B4=3000
470  C1=1000
480  J=1
1000  REM ** REPORT TO HAMURABI
1010  PRINT 
1020  PRINT "HAMURABI, I BEG TO REPORT THAT LAST YEAR"
1030  PRINT 
1040  PRINT A3;"PEOPLE STARVED AND";A2;"PEOPLE CAME TO THE CITY."
1050  IF J>0 THEN 1100
1060  A1=A1-INT(A1/2)
1070  PRINT "THE PLAGUE KILLED HALF THE PEOPLE."
1100  PRINT "THE POPULATION IS NOW";A1
1110  PRINT 
1120  PRINT "WE HARVESTED";B4;"BUSHELS AT";B3;"BUSHELS PER ACRE."
1130  PRINT "RATS DESTROYED";B2;"BUSHELS LEAVING";B1;
1140  PRINT "BUSHELS IN THE STOREHOUSES."
1150  PRINT 
1160  PRINT "THE CITY OWNS";C1;"ACRES OF LAND."
1170  C2=17+INT(6*RND(0))
1180  PRINT "LAND IS WORTH";C2;"BUSHELS PER ACRE."
1190  PRINT 
1200  PRINT 
1210  PRINT "HAMURABI . . ."
1300  REM ** BUY LAND?
1310  PRINT 
1320  PRINT "BUY HOW MANY ACRES";
1330  INPUT I
1340  I=INT(ABS(I))
1350  IF I=0 THEN 1500
1360  J=I*C2
1370  IF J <= B1 THEN 1400
1380  GOSUB 9000
1390  GOTO 1310
1400  B1=B1-J
1410  C1=C1+I
1500  REM ** SELL LAND?
1510  PRINT "SELL HOW MANY ACRES";
1520  INPUT I
1530  I=INT(ABS(I))
1540  IF I=0 THEN 1700
1550  IF I<C1 THEN 1600
1560  IF I=C1 THEN 9999
1570  GOSUB 9000
1580  GOTO 1510
1600  C1=C1-I
1610  B1=B1+C2*I
1700  REM ** DISTRIBUTE FOOD
1710  PRINT "HOW MANY BUSHELS SHALL WE DISTRIBUTE AS FOOD";
1720  INPUT I
1730  I=INT(ABS(I))
1740  IF I <= B1 THEN 1770
1750  GOSUB 9000
1760  GOTO 1710
1770  B1=B1-I
1780  A3=A1-INT(I/20)
1790  A2=0
1800  IF A3 >= 0 THEN 1900
1810  A2=-A3/2
1820  A3=0
1900  REM ** PLANT LAND
1910  PRINT "HOW MANY ACRES SHALL WE PLANT";
1920  INPUT I
1930  I=INT(ABS(I))
1935  IF I>C1 THEN 1960
1940  J=INT(I/2)
1950  IF J <= B1 THEN 1980
1960  GOSUB 9000
1970  GOTO 1910
1980  IF I>10*A1 THEN 1960
1990  B1=B1-J
2000  REM ** HARVEST, RATS, AND CHANGES IN POPULATION
2010  B3=INT(5*RND(0))+1
2020  B4=B3*I
2030  B2=INT((B1+B4)*.07*RND(0))
2040  B1=B1-B2+B4
2050  J=INT(10*RND(0))
2060  A2=INT(A2+(5-B3)*B1/600+1)
2070  IF A2 <= 50 THEN 2100
2080  A2=50
2100  A1=A1+A2-A3
2110  GOTO 1010
9000  REM ** ERROR SUBROUTINE
9005  PRINT 
9010  PRINT "HAMURABI, THINK AGAIN - YOU ONLY HAVE"
9020  PRINT A1;"PEOPLE,";C1;"ACRES, AND";
9030  PRINT B1;"BUSHELS IN STOREHOUSES."
9040  PRINT 
9050  RETURN 
9999  END