******************************************************
NAME:PIRATES  TYPE:BASIC FORMAT:ASCII  SA/LA:0000 0000
******************************************************

1 PCLEAR1:PMODE0,1:GOSUB1800
5 CLEAR:L=3:H=1:M=1
10 LL=83:II=63:VV=20:ON ERR GOTO1215
15 V1$="GOTALODRWEGIREGUGELIROPUOPSHJUSTDITISCIN"
20 N1$="THRDIVLOGCHEMATGUNCAPBOWCHAANCPOOQUABELCANSHIRUMONICROTREOGRFLASEAIGNLOCOARKEYSHOINSMAPCABFISLADPIRBOAOPEGOLBATMOACORSCAROPBUOCOWDOOSIGBUNFOORINDIARUBEMEJEWHALRATKITHOTPRENORSOUEASWESUP DOW"
25 GOTO1475
30 IF(F<>1ORI(21)<>0)AND((L>59ANDL<63)ORL=72ORL>74)THEN PRINT"IT' TOO DARK TO SEE MATE!!":GOTO1340
35 RETURN
40 :'
45 :'
50 :'
55 IFI(2)=1000AND(L<4ORL>62)ANDL<>79ANDL<>74THEN PRINT"IT'S TOO HOT TO MOVE MATE!!":GOTO1340:ELSE RETURN
60 G$="":IFI(47)=0OR((I(41)=0OR(I(41)=500ANDI(17)=0))AND(RG=1ORRD=1ORRC=1ORRB=1))THEN PRINT"CAN'T MATE":GOTO1340
65 IFN=34ANDL=5THEND=1:L(5,1)=6
70 IFN=19ANDL=79THEND=1:L(79,1)=83:TIDE=0:L(71,0)=0:L$(71)="CAVE ENTRANCE ...CAVE FLOODED BY TIDE!!":IFI(18)=79THENI(18)=83
75 IFD<0ORD>5THEN PRINT"NO SUCH DIRECTION,TRY AGAIN":GOTO1340
80 IFD=5ANDL>=6ANDL<63ANDI(2)<>1000THENPRINT"GASP!! I RAN OUT OF AIR HAD TO  COME UP MATE":GOTO1340
85 IFVERB$="RO"THEN1105
90 IFL=31ANDD=5THEN100
95 IF(L>6ANDL<=45)ANDD<>5OR(L=6ANDD=1)THENPRINT"BOAT WON'T !!!GO!!! MATE.":GOTO1340
100 IFL(L,D)=74THENL(74,4)=L
105 IFL(L,D)<>0THENL=L(L,D)
110 IFL=82THENL(63,4)=82
115 IFL<>31ORANC=1ORD<>4THEN125
120 R$(0)="HELP!!THE BOAT HAS DRIFTED AWAY":R$(1)="IT'S TOO FAR TO SWIM TO SHORE!!":R$(2)="HOW LONG CAN YOU TREAD WATER!!":A$="ACTION":FORX=0TO2:FORY=1TO100:PRINTR$(X):NEXTY,X:GOTO245
125 L$(6)="OCEAN NEAR WARF":IFL<=6THENL$(6)="BOAT AT WARF"
130 IFL>45ANDL<63ANDTS=0THENTS=1:TIMER=0:A1=0:A2=0
135 IFL<46ORL>62THEN TS=0:A1=0:A2=0
140 IFL>71ANDTT=0THENTT=1:TIMER=0:A1=0:A2=0
145 IFL<72ORL>81THENTT=0:A1=0:A2=0
150 CLS:PRINT"blimey my location is:"
155 GOSUB40
160 IFL>6ANDL<46THENPRINT"IN BOAT AT:";
165 PRINTL$(L)
170 PRINTG$
175 GOSUB220
180 GOSUB330
185 IFL=62ANDM<>0THENL=60
190 IFL=60ANDM<>0THENR$(0)="THE HATCH HAS FALLEN SHUT.":R$(1)="I CAN'T GET IT OPEN.":R$(2)="I'M DROWNING....I'M DEAD.":R$(3)="THE FIRST LAW OF DIVING IS :":R$(4)="NEVER DIVE ALONE!!!!":FORX=0TO4:FORY=1TO100:PRINTR$(X):NEXTY,X
195 IF(L=60ORL=62)ANDM<>0THEN305
200 IF(L=73ANDP=0ANDD=1)OR(L=71ANDD=1ANDP=0)THENPRINT"YIKES!!!  PIRANHAS IN MOAT.  I'M EATEN.":A$="ACTION":GOTO295
205 IFL=78ANDRAT=0ANDSKU=0THENRAT=1
210 IFSKU=1AND(L=78ORL=79)THENPRINT"PEW...IT STINKS IN HERE MATE."
215 GOTO1340
220 PRINT:I=0:PRINT"i see"
225 IF(I(40)=0ANDI(43)=L)THENCOW=1
230 IFCOW=1ANDL>63ANDL<83THENI(43)=L
235 IFRC=1THENI(41)=I(43)
240 IFL=63THEN260
245 FORX=1TOII:IFI(X)<>L THENNEXTX:GOTO260
250 PRINTI$(X):I=1:IFX<II THENNEXTX
255 PRINTI$(X):I=1:IFX<II THEN NEXTX
260 IF(L>=6ANDL<46ORL=63)THENFORX=1TOII:IF(I(X)<>101ANDI(X)<>6)THENNEXTX:GOTO270
265 IF(L>=6ANDL<46ORL=63)THENIF(L<>6ORI(X)<>6)THENPRINTI$(X):I=1:IFX<II THENNEXTX
270 IFM=0THENPRINTI$(5)
275 IFI=0ANDM<>0THENPRINT"NOTHING OF INTEREST"
280 IFRD=1ANDRC=1ANDC=1ANDI(43)<>76ANDST<>1THENI$(44)="IRON DOOR PULLED OPEN BY COW    WHEN IT MOVED TO EAT THE HAY IN THE SCARECROW.":ST=1:I(40)=100:COW=0:L(76,0)=77:H=H-1
285 IFC=5THENC=1:PRINT"i hear":PRINT"CREEK CREEK MUNCH MUNCH":COW =0
290 Y=0:FORX=0TO5:Y=Y+L(L,X):NEXTX:A$="COURSE":IFY<>0ORL=62THEN310
295 PRINT:PRINT"THE LAST ";A$;"  WAS FATAL TO MY LIFE --SOME MATE YOU TURNED OUT TO BE!!!":PRINT:PRINT:PRINT
300 IFL>6ANDL<46THENPRINT"YOU HAD BETTER MAP THESE WATERS MATE"
305 PRINT"YOU MUST NOW STAT OVER":FORX=1TO4000:NEXTX:GOTO5
310 RETURN
315 :'***INVENTORY***
320 PRINT:PRINT"i'm carrying":FORX=1TOII:IFI(X)=0THENPRINTI$(X):NEXTX
325 GOTO1340
330 :'
335 PRINT"obvious bearings are:"
340 FORX=0TO5:IFL(L,X)<>0THENPRINTDI$(X);  
345 IFX<5THENNEXTX
350 PRINT
355 RETURN
360 :'
365 GOSUB30
370 IFN=17ANDI(17)=0THENPRINT"ONION SACK CONTAINS:":I=0:FORX=1TOII:IFI(X)<>500THENNEXTX:GOTO380
375 IFN=17ANDI(17)=0THENPRINTI$(X):I=1:NEXTX
380 IFN=17ANDI(17)=0ANDI=0THENPRINT"NOTHING":GOTO1340
385 PRINT"i see";
390 IFN=38AND(L=73ORL=71)THENI(31)=73
395 IFN=4ANDI(4)=0ANDMA<>1ANDC=1AND(L<46ORL>62)THEN PRINT"AAHHH A MAP!!!":I(29)=L:Q=1:MA=1:IFL>6ANDL<46THENI(29)=101:GOTO1340
400 IFN=29ANDI(29)-0ANDMA<>11ANDC=2AND(L<46ORL>62)THEN PRINT"POINT MARKED X ON NORTH SIDE OF DEVILS ISLAND.":GOTO1340
405 IFQ=1THENQ=0:GOTO1340
410 IFN=20ANDL=71ANDI(3)=100ANDL(71,0)=72THENI(3)=71
415 IFN=5ANDM=0ANDL<>13THENPRINTLI$(5):GOTO1340
420 IF(I(N)=0ORI(N)=L OR(N=28ANDI(4)=0)OR(I(N)=101ANDL>5ANDL<46))ANDN<=II THENPRINTLI$(N):GOTO1340
425 IFD>-1AND(L=20ORL=21ORL=25ORL=29ORL=33ORL=35ORL=39)THEN PRINT"FOG.  NOTHING BUT FOG MATE.":GOTO1340
430 IFD>-1THEN PRINTL$(L(L,D)):IFL<>78ANDL(L,D)=0THEN PRINT"NOTHING OF INTEREST.":GOTO1340
440 IFD>-1ANDL=78ANDD<>4ANDD<>1THEN PRINT"NOTHING OF INTEREST":GOTO1340
445 IFL=78ANDD=4ANDI(19)=100THEN PRINT"LARGE AND HEAVY WOODEN TREASURE CHEST, SUSPENDED BY CABLE AND   PULLEY, HIGH OVER PIT.":I(19)=L:GOTO1340
450 GOTO1340
455 GOTO1340
460 :'
465 IFH>1THENPRINT"HANDS TOO FULL MATE.":GOTO1340
470 IFN=2ANDI(2)=0THENI(2)=1000:H=H-1:PRINT"WEARING IT MATE":GOTO1340
473 IFN=2ANDI(2)<>0THEN PRINT"DON'T HAVE IT MATE.":GOTO1340
475 PRINT"DON'T BE DAFT MATE!!":GOTO1340
480 :'
485 IFN<>21THEN GOSUB30
490 IFN=36ANDI(36)=100THEN PRINT"MATE WON'T GIVE IT BACK.":PRINT:PRINT"MATE WISHES TO USE  IT TO BUY FOOD.":I$(5)="NOT SO "+I$(5):GOTO1340
495 IFN=5AND(L=13ORM=0)THENPRINT"!!SLAP!!  FRESH!!":GOTO1340
500 IF(N>4ANDN<16)OR(N>18ANDN<24ANDN<>24ANDN<>21)OR(N>27ANDN<36ANDN<>29ANDN<>32)OR(N>41ANDN<47)ORN=54ORN=57THEN PRINT"IMPOSSIBLE MATE":GOTO1340
505 IFN=53ANDI(43)=L ANDC=1THENC=0:LI$(43)="BROWN COW":I$(43)="COW":GOTO545
510 IF((L>=6ANDL<46)ORL=63)ANDI(N)<>0ANDI(N)<>101ANDI(N)<>L ANDI(N)<>6AND(I(17)<>0ORI(N)<>500)AND(L<>13ANDI(N)<>13)THEN PRINT"IT AIN'T IN THE BOAT MATE":GOTO1340
515 IF(L>=6ANDL<46)ORL=63THEN525
520 IFI(N)<>L AND(I(17)<>0ORI(N)<>500)THENPRINT"IT AIN'T HERE MATE":GOTO1340
525 IFH>2THEN PRINT"MY HANDS ARE FULL!!CARRY IT     YOURSELF":GOTO1340
530 IFI(N)=500ANDI(17)=0THENO=O-1
535 IF N=39 AND L=2 THEN PRINT"NOT RIPE YET MATE.":GOTO1340
540 IFN=26ANDIG=1ANDL>5ANDL<46THENIG=0:I(26)=0:H=H+1:GOTO1340
545 IFN<=II THENI(N)=0:PRINT"I GOT IT":H=H+1:IFN=25ORN=24THENR=0
547 IFI(47)=0THENI$(47)="FOOTLOCKER"
550 IFN=3ANDI(3)=0THENLI$(20)="OGRE PASSED OUT"
555 IFI(4)=0ANDL=62ANDDAN=0THENDAN=1:PRINT"THE WRECK HAS SHIFTED MATE.":PRINT"THE HATCH HAS FALLEN SHUT AND":PRINT"SOMETHING HEAVY HAS FALLEN ON IT":PRINT"I'M TRAPPED":L(L,4)=0:L(56,5)=0:A=1
560 IFN=32THENL$(73)="PATH !! MOAT BLOCKING WAY":L(73,0)=71
565 IFN>II THEN1215
570 GOTO1340
575 :'
580 IFN>II ORI(N)<>0THENPRINT"DON'T HAVE IT MATE":GOTO1340
585 IFL>6ANDL<46ANDL<>13THEN615
590 IFN=40AND COW=1THEN PER$="COW":GOTO672
595 I(N)=L:PRINT"THERE SHE GOES":H=H-1:IFN<>55AND N<>47THEN1340
600 IFN=47THENB=1:I$(47)="FOOTLOCKER ON CABIN DECK":GOTO1340
605 IFN=55ANDSKU=0ANDL=78THENPRINT"SKUNK SEE'S RATS.SKUNK RELEASES SCENT.":PRINT:PRINT"RATS ARE LEAVING QUICKLY.":SKU=1:I(54)=100:L(78,5)=79:GOTO1340
610 GOTO1340
615 I(N)=L(L,5):PRINT"THERE SHE GOES MATE, IT SUNK TOO":H=H-1:IFI(N)=0THENI(N)=100
620 IFN=42ANDRG=1THENPRINT"ANCHORED MATE":ANC=1:H=H-1
625 IFN=41ANDRG=1THENI(42)=I(41)
630 GOTO1340
635 :'
640 IFI(N)<>0ORN>II THENPRINT"CAN'T GIVE WHAT I AIN'T GOT":GOTO1340
645 INPUT"GIVE TO WHOM??";PER$:PER$=LEFT$(PER$,3)
650 IFN=16ANDL=71ANDPER$="OGR"THEN PRINT"THE DEED IS DONE":I(16)=100:L(71,0)=72:L$(71)="CAVE ENTRANCE":H=H-1:PRINT"i hear";"WHUMP THUD!!":LI$(20)="O"
655 IFLI$(20)="O"THENLI$(20)="OGRE PASSED OUT....LOG BOOK IN OGRE'S POCKET":GOTO1340
660 IFN=56ANDL=13ANDPER$="MAT"THENPRINT"MATE SAYS---YOUR HUMBLE SERVANT MATE":M=0:I$(5)="WELL FED AND HUMBLE MATE":H=H-1:LI$(5)="POOR,BUT WELL FED HUMBLE    MATE":I(56)=100:GOTO1340
665 IFN=36ANDL=13ANDPER$="MAT"THENPRINT"MATE SAYS--THANKS":I(36)=100:I$(5)="THANKFUL MATE":H=H-1:LI$(5)="STARVING WRETCH":GOTO1340
670 IFN=36ANDL=3AND(PER$="PRE"ORPER$="ATT")THENPRINT"PRETTY ATTENDANT GIVES YOU HOT- DOGS IN RETURN.":I(36)=100:I(56)=0:GOTO1340
671 IFPER$="FIS"AND(L=71ORL=73)THENH=H-1:I(N)=100:PRINT"SPLOOSH...GONE":GOTO1340
672 IFN=40ANDPER$="COW"THENI(40)=100:PRINT"MUNCH MUNCH MUNCH":COW=0:ST=1:H=H-1:GOTO1340
673 IF(PER$="MAT"ANDL<>13)OR(PER$="OGR"ANDL<>71)OR((PER$="PRE"ORPER$="ATT")ANDL<>3)THEN PRINT"NOT HERE MATE":GOTO1340
675 PRINT"DOESN'T WANT IT":GOTO1340
680 H=H-1:GOTO1340
685 :'
690 IFI(N)<>0ORN>II THENPRINT"I AIN'T GOT IT":GOTO1340
695 IFN<>16THENPRINT"DON'T BE DAFT YOU'VE BEEN AT SEE TO LONG":GOTO1340
700 IFR<>1THENPRINT"LABEL SAYS--OPEN ME FIRST":GOTO1340
705 R$(0)="AAAHHH":R$(1)="OH OH,TOO LATE":R$(2)="MY HEADS SPINNING":R$(3)="WHERE'S THE HEAD":R$(4)="OOPS SORRY MATE SHOULD'VE MOVED":R$(5)="I'M AFRAID I'M GOING TO DIE":R$(6)="MY HEAD ACHES"
710 R$(7)="I'M AFRAID I'M GOING TO LIVE":R$(8)="WOULD SOMEONE PLEASE KILL ME":R$(9)="I SURVIVED NO THANKS TO YOU"
715 FORX=0TO9:FORY=1TO100:PRINTR$(X):NEXTY,X
720 GOTO1340
725 :'
730 GOSUB30
735 IFL=78ANDN=30ANDI(30)=L THENR$(0)="THE TREASURE CHEST IS FALLING.":R$(1)="CABLE IS RAPIDLY RISING!!":R$(2)="MY ARM IS CAUGHT IN THE CABLE":R$(3)="I'M BEING DRAGGED UP":R$(4)="I'VE HIT THE CAVE ROOF"
740 IFL=78ANDN=30THENR$(5)="I'M FALLING.":R$(6)="SPLAT I'M SIX CM SHORTER MATE!":FORX=0TO6:FORY=1TO100:PRINTR$(X):NEXTY,X:I(19)=79:I(30)=100:GOTO1340
745 IFL=50ANDN=10THENPRINT"ANCHORS AWAY--OUT GOES THE CHAIN":I(9)=100:I(10)=100:I(35)=60:L(60,3)=61:GOTO1340
750 IFL=6ANDN=34THENPRINT"O,K, I'VE CAST OFF!!":I(34)=100:GOTO1340
755 IFN>II THEN1215
760 IFN=44ANDRD=1ANDL=76THENRD=0:GOTO785
765 IF(N=43ORN=53)ANDRC=1ANDI(43)=L THENRC=0:GOTO785
770 IFN=42ANDRG=1ANDL=31THENRG=0:RB=0:ANC=0:GOTO785
775 IFN=34ANDRB=1ANDL=31THENRB=0:ANC=0:RG=0:GOTO785
780 PRINT"CAN'T BE DONE MATE":GOTO1340
785 PRINT"DONE MATE.":GOTO1340
790 :'
795 IFL>=6ANDL<46ANDN=22ANDI(21)=100THENPRINT"AVAST!  A FLASH OF LIGHT":I(37)=6:I(21)=6:I(22)=100:GOTO1340
800 IF(N=42OR(N=41ANDRG=1))AND(I(41)=L ORI(42)=L)THENANC=0:PRINT"O.K.  I DID THAT MATE.":I(42)=L:GOTO1340
805 IFN=46ANDL=62ANDB=1THENPRINT"AVAST!!! A HIDDEN PASSAGEWAY.":L(L,5)=61:L(61,4)=62:A=0:GOTO1340
810 PRINT"NOTHING USEFULL ACCOMPLISHED":GOTO1340
815 :'
820 GOSUB50
825 IFI(N)<>0ORN>II THENPRINT"DON'T HAVE IT":GOTO1340
830 PRINT:INPUT"WHERE?";PU$:PU$=LEFT$(PU$,3):N1=N:T=1:NOUN$=PU$:GOSUB1415:T=0
835 IFN1=37ANDF=2ANDN=21THENI(37)=100:PRINT"DONE":H=H-1:F=1:GOTO1340
840 IFLEFT$(PU$,2)="DO"THENN=N1:GOTO595
845 IFN1=26ANDN=23THENI(26)=200:IG=1:H=H-1:GOTO1340
850 IFN=34AND((L>=5ANDL<46)ORL=63)THENGOTO1080
855 IFN1=25ANDN=24ANDL>=6ANDL<46ANDI(24)=101THENPRINT"OARS LOCKED":H=H-1:R=1:I(25)=101:GOTO1340
860 IFN1=53ANDN=43ANDI(N)=L THENC=1:I(53)=100:H=H-1:I$(43)=I$(43)+" WEARING "+I$(53):PRINT"DONE":LI$(43)=LI$(43)+" WEARING "+I$(53):GOTO1340
865 IFN1=26ANDN=23THENIG=1:I(26)=101:H=H-1:GOTO1340
870 IF(PU$="FIS"ORPU$="MOA")ANDN1<>32THENH=H-1:I(N1)=100:PRINT"SPLOOSH":GOTO1340
875 IFN1=1ANDN=19ANDI(19)=L THENPRINT"CLICK":TC=1:H=H-1:I(1)=L:GOTO1340
880 IFN1=17ANDO>9THENPRINT"ONION SACK TOO FULL MATE.":GOTO1340
885 IF(N1=47ORN1=40ORN1=25ORN1=32)ANDN=17THENPRINT"WON'T FIT MATE":GOTO1340
890 IFN=17ANDI(17)=0THENO=O+1:I(N1)=500:PRINT"IT FIT":H=H-1:GOTO1340
895 IFL=73ANDN1=32ANDN=38THENP=1:I(N1)=L:L$(73)="LADDER BRIDGING MOAT":L(L,0)=71:L(71,1)=L:H=H-1:GOTO1340
900 IFPU$="OCE"OR(L>6ANDL<46ANDPU$="DO")THENI(N1)=L(L,5):H=H-1:IFPU$="DO"THENH=H+1
905 IFN1=42ANDRG=1ANDI(42)=0THENH=H-1:I(42)=I(41):GOTO1340
910 IFN1=41ANDRG=1THENI(42)=I(41):GOTO1340
915 IFN=42THEN620
920 PRINT"THAT CAN'T BE DONE MATE":GOTO1340
925 :'
930 GOSUB30
935 IFI(21)=0ANDN=21ANDI(26)=100THENPRINT"AVAST A KEY":F=2:I(26)=L:X=500:IFL>6ANDL<46THENI(26)=101:GOTO1340
940 IFX=500THEN GOTO1340
945 IFN=21ANDI(21)=0ANDI(37)=200THENF=2:I(37)=L:PRINT"CLUNK":GOTO1340
950 IFI(12)=L AND(NOUN$="HAT"ORN=12)THENPRINT"HEAVY BUT IT OPENED":L(56,5)=62:L(62,4)=56:GOTO1340
955 IFI(11)=L AND(NOUN$="HAT"ORN=11)THEN PRINT"HEAVY BUT IT OPENED MATE.":L(49,5)=60:L(60,4)=49:GOTO1340
960 IFI(4)=0ANDL>45ANDN=4ANDL<63THENPRINT"OH NO!! A MUSHY GLOB THAT USED  TO BE A MAP IS NOW UNREADABLE":MA=11:GOTO1340
965 IFN=19ANDTC=1ANDI(19)=L THENPRINT"SHIVER ME TIMBERS MATE":I(18)=L:PRINT"AVAST!!THE TIDE IS RISING!!CAVE FLOODING":TIDE=TIDE+1:GOTO1340
970 IFI(16)=0ANDN=16THENPRINT"SMELLS VERY STRONG":R=1:GOTO1340
975 IFI(4)=0ANDN=4AND(L<46ORL>62)THENPRINT"OPENED":C=1:GOTO1340
980 IFI(29)=0ANDC=1THENPRINT"OH GREAT!!!":C=2:I$(29)="MAP":LI$(29)="POINT MARKED X ON NORTH SIDE OF DEVIL'S ISLAND":GOTO1340
985 IFN=47ANDL=62THENPRINT"AVAST!!":I(16)=62:GOTO1340
990 IFN>II ANDNOUN$<>"HAT"THEN1215
995 IFN=44ANDL=76THENPRINT"HINGES TOO RUSTY MATE":GOTO1340
1000 PRINT"CAN'T MATE":GOTO1340
1005 :'
1010 PRINT"i'm holding:"
1015 FORX=1TOII:IFI(X)<>0THENNEXTX:GOTO1025
1020 PRINTI$(X):NEXTX
1025 PRINT:PRINT"i'm wearing:":FORX=1TOII:IFI(X)<>1000THENNEXTX:GOTO1035
1030 PRINTI$(X):NEXTX
1035 GOTO1340
1040 :'
1045 IFI(N)<>1000ORN>II THENPRINT"I'M NOT WEARING THAT MATE":GOTO1340
1050 IFH>0THENGOSUB1795:GOTO1340
1055 I(N)=0:H=H+1:PRINT"OK I'VE SHED IT MATE"
1060 GOTO1340
1065 :'
1070 IFN=38ANDL=73THENPRINT"IT WAS TOO FAR MATE":P=0:DI$="NO":GOTO200
1075 PRINT"NO WAY MATE":GOTO1340
1080 :'
1085 IFN1=24THENPRINT"OAR LOCKS IN PLACE":H=H-1:I(24)=101:GOTO1340
1090 I(N1)=101:H=H-1:PRINT"STOWED SAFELY MATE"
1095 IFN1>II THEN1215
1100 GOTO1340
1105 :'
1110 IFH>0THENGOSUB1795:GOTO1340
1115 IFD>3THENPRINT"CAN'T DO THAT MATE":GOTO1340
1120 IFI(25)<>101ANDI(25)<>0THENPRINT"NO OARS MATE":GOTO1340
1125 IF(I(25)=101ORI(25)=0)AND(L=6OR(L>=45ANDL<63))ANDR<>1THENPRINT"OARS NOT LOCKED":GOTO1340
1130 IFL=6ANDLEFT$(NOUN$,2)="NO"THENPRINT"THERE'S A WARF IN THE WAY MATE":GOTO1340
1135 IFI(34)<>100ORANC=1THENPRINT"I'M ROWING BUT NOT GOING MATE":GOTO1340
1140 IF(L(L,D)>6ANDL(L,D)<11)ORL(L,D)=13ORL(L,D)=15ORL(L,D)=26ORL(L,D)=36THENGOSUB1150
1145 GOTO105
1150 :'
1155 IFL(L,D)>6ANDL(L,D)<11THENZ=-1:Z1=1:FORY=0TOD+1:Z1=Z1*Z:NEXTY:L(L(L,D),D+Z1)=L
1160 G1$=G1$+"GREATLY "
1165 G$=G1$+"DEMORALIZED AND AGROUND  MATE"
1170 RETURN
1175 :'
1180 IFIG<>1THENPRINT"NO KEY MATE":GOTO1340
1185 IFL>=6ANDL<46ANDIG=1THENPRINT"ENGINE WON'T START AND CANNOT BE REPAIRED DUE TO NEGLECT MATE":I(23)=100:GOTO1340
1190 :'
1195 IFL>=6ANDL<63THENPRINT"SPLASH SPLASH":GOTO1340
1200 IFI(27)<>0THENPRINT"THIS IS TOO HARD ON THE HANDS   MATE.":GOTO1340
1205 IFI(27)=0ANDL<>1THENPRINT"NOTHING MATE":GOTO1340
1210 IFI(27)=0ANDL=1THENPRINT"CLINK":I(24)=1:GOTO1340
1215 :'
1220 PRINT"INPUT ERROR,PLEASE RETYPE MATE"
1225 PRINT:PRINT"CHECK TO SEE THAT THE noun YOU  USED MATCHES THE ITEM LISTED.":GOTO1340
1230 :'
1235 GOSUB30
1240 IFI(N)<>0ORN>II THENPRINT"DON'T HAVE IT MATE":GOTO1340
1245 INPUT"TIE TO WHAT MATE?";TIE$:TIE$=LEFT$(TIE$,3):N1=N:NOUN$=TIE$:T=1:GOSUB1415:T=0:IFI(N)<>L ANDN<>34THEN PRINT"NOT HERE MATE!!":GOTO1340
1260 IF(N=43ORNOUN$="HAL")ANDC=1THENRC=1:PRINT"ROPE TIED TO COW MATE":I(41)=L:H=H-1:GOTO1285
1265 IFN=44THENRD=1:PRINT"ROPE TIED TO DOOR MATE":I(41)=76:H=H-1:GOTO1285
1270 IFN=34AND((L>4ANDL<46)ORL=63)THENRB=1:PRINT"ROPE TIED TO BOAT MATE":I(41)=101:GOTO1285
1275 IFN=42THENRG=1:PRINT"ROPE TIED TO BUOY MATE":I(41)=101:GOTO1285
1280 PRINT"DON'T BE FOOLISH MATE":GOTO1340
1285 H=H-1:IFRB=1ANDRG=1THENANC=1
1290 GOTO1340
1295 :'
1300 IFL<>3THENPRINT"YOU'RE NOT FINISHED YET MATE":PRINT"THERE ARE 7 TREASURES IN ALL.":GOTO1340
1305 IFI(1)=0ORI(1)=82OR(I(17)=0ANDI(1)=500)THENSC=SC+1
1310 IFI(18)=0ORI(18)=3OR(I(17)=0ANDI(18)=500)THENSC=SC+1
1315 FORX=48TO52:IFI(X)=0ORI(X)=3OR(I(17)=0ANDI(X)=500)THENSC=SC+1
1320 NEXTX
1325 PRINT"YOU HAVE";SC;"TREASURES OUT OF      7 MATE"
1330 IFSC=7THEN PRINT"CONGRATULATIONS ON A SUCCESSFUL TREASURE HUNT MATE--SEE YOU SOON IN ANOTHER GAME":END
1335 GOTO1340
1340 :'
1345 IFL>70ANDL<82ANDL<>73ANDL<>74ANDAI>3THENSOUND200,30:PRINT"THE OGRE HAS AWAKENED!!!":IFAI>4THENSOUND200,20:PRINT"THE OGRE'S HERE,I DIED SLOWLY!!":GOTO305
1350 IF TS=1 AND TIMER>A1 THEN A1=TIMER:GOTO1370
1355 IFTS=1THEN A1=0:TIMER=0:A2=A2+1:IFA2>0THEN PRINT"AIR LOW MATE!!":FORX=1TO2000:NEXTX:IFA2=2THEN PRINT"AIR HAS RUN OUT MATE!!!":GOTO305
1360 IF TT=1 ANDTIMER>A1 THENA1=TIMER:GOTO1370
1365 IFTT=1THEN A1=0:TIMER=0:A2=A2+1:IFA2>0THEN PRINT"THE OGRE'S COMING!!!":FORX=1TO2000:NEXTX:IFA2=2THEN PRINT"THE OGRE'S HERE. I DIED SLOWLY!":GOTO305
1370 PRINT:INPUT"what now mate?";ANS$:NOUN$=" ":D=-1
1375 H=0:FORZZ=1TOII:IFI(ZZ)=0THENH=H+1
1376 NEXTZZ
1380 IFLEN(ANS$)<5AND LEFT$(ANS$,2)="LO"THEN 150
1385 IFANS$="INV"THENGOSUB1005
1390 IFLEFT$(ANS$,4)="VERB"THENGOTO1605
1395 FORX=1TOLEN(ANS$)
1400 IFMID$(ANS$,X,1)<>" "THEN NEXTX
1410 IFLEN(ANS$)>=X+3THEN NOUN$=MID$(ANS$,X+1,3)
1415 FORX=1TOII:IFMID$(N1$,3*X-2,3)<>NOUN$ THEN NEXTX
1430 N=X:IFT=1THENRETURN
1435 IFN>57ANDN<64THEND=N-58
1440 IFN=II+1ANDRIGHT$(ANS$,2)="UP"THEND=4
1445 VERB$=LEFT$(ANS$,2)
1450 FORX=1TOVV:IFVERB$<>MID$(V1$,2*X-1,2)THENNEXTX
1455 IFTIDE>0THEN TIDE=TIDE+1:IFTIDE>4THENA$="ACTION":PRINT"I'M DROWNING,NO AIR TO BREATH   AND I'M TOO TIRED TO SWIM":GOTO295
1460 IFRA>0ANDSKU=0THENRA=RA+1:IFRA>4ANDL=77THENA$="ACTION":PRINT"I'M BEING EATEN ALIVE BY BIG    HUNGRY RATS...I'M DEAD MATE":GOTO295
1465 ONX GOTO60,480,360,575,460,635,725,685,480,790,60,815,925,1040,1065,1175,1190,1230,1295,1005
1470 PRINT"I DON'T KNOW HOW MATE":GOTO1340
1475 DIML(LL,5),I$(II+1),I(II+1),VERB$(VV+1),DI$(5),L$(LL),LI$(II+1)
1480 CLS:PRINT@201,"LOADING DATA"
1485 FORX=1TOLL:FORY=0TO5:READL(X,Y):NEXTY:NEXTX
1490 FORX=1TOLL:READL$(X):NEXTX
1495 FORX=1TOII:READI$(X):READI(X):NEXTX
1500 FORX=0TO5:READDI$(X):NEXTX
1505 FORX=1TOVV:READVERB$(X):NEXTX
1510 FORX=1TOII:READLI$(X):NEXTX
1515 CLS:PRINT@138,"RANDOMIZING":PRINT@174,"SOME":PRINT@198,"TREASURE LOCATIONS"
1520 FORX=48TO52
1525 I(X)=INT(RND(81)):IFI(X)<47ORI(X)>81ORI(X)=74OR(I(X)>62ANDI(X)<71)THEN1525
1530 NEXTX
1535 FORJ=1TO3000:NEXTJ
1540 CLS::'****STORY****
1545 PRINT"YOU HAVE THE FOLLOWING          INFORMATION WRITTEN BY A PIRATE WHO SURVIVED THE SINKING        OF HIS VESSEL."
1550 PRINT:PRINT"MANS GREED LIES BETWEEN         THE DEVIL AND THE ANGEL         IN THE DEEP BLUE SEA."
1555 PRINT:PRINT"THE LOCATION WILL BECOME CLEAR  BUT MAN'S GREED COULD COST DEAR."
1560 PRINT:PRINT:INPUT"PRESS<ENTER>TO CONTINUE";Z$:Z$=INKEY$:IFINKEY$=CHR$(13)THEN1565
1565 CLS:PRINT"YOU HAVE YOUR LIFE SAVINGS      IT'S IN GOLD COIN,BUT           YOU NEED A TREASURE TO RETIRE.":PRINT:PRINT:INPUT"PRESS<ENTER>TO CONTINUE:";Z$:Z$=INKEY$:IFINKEY$=CHR$(13)THEN1570
1570 CLS::'***INSTRUCTIONS***
1575 PRINT"ENTER TWO WORD COMMANDS.        FIRST A VERB THEN A NOUN."
1580 PRINT"EXM...GO NORTH"
1585 PRINT:PRINT"SOME COMMANDS NEED A THIRD WORD":PRINT"EXM...THE COMMAND put money ":PRINT:PRINT"YOU WILL THEN BE ASKED where"
1590 PRINT:PRINT"YOU THEN ENTER A location"
1595 PRINT:INPUT"PRESS<ENTER>TO CONTINUE";Z$:Z$=INKEY$:IFZ$=CHR$(13)THENCLS:GOTO1600
1600 CLS::'****VERB LISTING****
1605 PRINT"SOME VERBS AVAILABLE  ARE:":PRINT
1610 PRINT"guzzle release wear shed start "
1615 PRINT:PRINT:PRINT"TO LIST WHAT YOU'RE HOLDING OR  WEARING AT ANY TIME TYPE IN inv"
1620 PRINT:PRINT"TO LIST THESE VERBS AGAIN TYPE  verbs "
1625 PRINT:PRINT"should an error occur type goto 1340"
1630 PRINT:INPUT"PRESS <ENTER> TO CONTINUE.";Z$:Z$=INKEY$:IFZ$=CHR$(13)THEN1635
1635 CLS
1640 :'
1645 DATA,3,,,,,,,,3,,,1,5,2,4,,,,,3,,,,3,,,,,,5,45,,,,74,,,,,,,,,,,,,,,,,,,,,,,,,7,15,8,12,,,7,16,11,45,,74,,16,45,14,,,,19,13,9,,74,11,,,16,,,12,21,15,17,,74,45,22,16,18,,74
1650 DATA13,23,17,19,,74,,,,,,,15,25,8,21,,,16,26,20,22,,,17,27,21,23,,74,18,28,22,24,,74,19,29,23,9,,74,20,30,8,26,,74,21,31,25,27,,,22,32,26,28,,74,,,,,,,24,34,28,9,,74,25,35,8,31,,74
1655 DATA63,36,30,32,,46,27,37,31,33,,74,28,38,32,34,,74,29,39,33,9,,74,30,40,8,36,,74,31,41,35,37,,,32,42,36,38,,74,,,,,,,34,44,38,9,,74,,,,,,,36,10,40,42,,74,37,10,41,43,,74
1660 DATA38,10,42,44,,74,39,1,43,45,,74,6,17,12,13,,74,,,,47,31,,,,46,49,31,,49,,,51,31,,50,48,47,52,31,,,49,,53,31,,52,,48,54,31,,53,51,49,55,31,,,52,50,56,31,,55,,51,57,31,,56,54,52,58,31,
1665 DATA,55,53,59,31,,58,,54,,31,,59,57,55,,31,,,58,56,,31,,,,,,49,,,,60,,,,,,,,56,,,31,64,65,,,68,,,63,,,66,,63,,,,69,65,67,,,,70,,68,66,,,,,,,,,73,66,70,,,
1670 DATA,67,,69,,,,,,,,,,71,75,76,,,,69,,,,,,,,,,,,,,72,,,,,72,,,,78,76,,,,,,77,,,,,,,,,78,,,83,,81,,,,,80,82,,,,,81,,,63,80,,,,,
1675 DATA SANDPIT,CORNFIELD,START,BEACH,WHARF,BOAT AT WHARF,NORTH SHORE,EAST SHORE,WEST SHORE,SOUTH SHORE
1680 DATASTREAM MOUTH,OCEAN,LIGHTHOUSE,OCEAN,DELTA,OCEAN & RAIN,OCEAN,ROUGH SEAS,KILLER WAVE,FOG
1685 DATAFOG,OCEAN,CALM SEAS,OCEAN, FOG,DEVELS ROCK,OCEAN,OCEAN,FOG,OCEAN
1690 DATAOCEAN,OCEAN,FOG,OCEAN,FOG,ANGEL ISLAND,OCEAN,REEF,FOG,DEAD HEAD
1695 DATAOCEAN,OCEAN ROLLERS,OCEAN,OCEAN,OCEAN,SEA BOTTOM,BOW SPRITE,POOP DECK NEAR CAPSTAN,POOP DECK,POOP DECK NEAR GUNWALE
1700 DATAMIDSHIP NEAR CANNON,MIDSHIP,MIDSHIP NEAR BELAYING PINS,QUATERDECK NEAR GUNWALE,QUATER DECK,QUATERDECK NEAR HATCH,QUATERDECK,QUATERDECK NEAR SHIPS WHEEL,QUATERDECK,CHAIN LOCKER
1705 DATAHOLD BELOW MIDSHIPS,CAPTAINS QUATERS,CALM LANDING BAY ON DEVILS      ISLAND,SAND DUNE,ISLAND SHORE,PATH,ROCK CLIFF,SWAMP,PATH,BUSH,CAVE ENTRANCE--OGRE BLOCKING WAY,CAVE INTERIOR
1710 DATAPATH BLOCKED BY MOAT,EMPTY SEA BOTTOM,COW STABLE,CAVE GROTTO,CAVE CORRIDOR,CAVE CHAMBER,PIT,LEDGE,TUNNEL,MEADOW ABOVE LANDING BAY,TREASURE CHEST--AFLOAT ON WATER
1715 DATATHREE SILVER PINS,61,  DIVING GEAR,5,LOGBOOK,100,CHEST--CAPTAINS,62,MATE,13,GUNWAL,54,CAPSTAN,48,BOWSPRITE,47,CHAIN ATTACHED TO ANCHOR,60,ANCHOR-HANGING BUT SECURED TO   DECK,50
1720 DATAPOOPDECK HATCH,49,QUARTERDECK HATCH,56,BELAYING PINS,53,CANNON,51,SHIPS WHEEL,58,RUM BOTTLE-FULL,100,ONION SACK,4,CROWN,100,TREASURE CHEST,100,OGRE,71,FLASHLIGHT,100,SEAT IN BOAT,101,IGNITION KEY SLOT,101
1725 DATALOCKS FOR OARS,100,OARS,1,KEY,100,SHOVEL,5,INSCRIPTION,100, MAP,100,CABLE SECURED TO WALL,78,FISH IN MOAT,100,LADDER,67,PIRANHAS,100,BOAT-SEATS SIX,5,OPENING IN BULKHEAD,100,GOLD COINS,0,BATTERIES D SIZE,100,MOAT,73
1730 DATACORN,2,SCARECROW,2,ROPE,6,BUOY,31,COW,75,DOOR MADE OF IRON,76,SIGN,3,BUNK,62,FOOTLOCKER ON BUNK,62,RING OF GOLD ,100,DIAMOND BRACELET,100,RUBY NECKLACE,100,EMERALD STUDDED DAGGER,100
1735 DATAJEWELED SEPTOR,100,HALTER ,2,RATS---BIG....MEAN....HUNGRY----BLOCKING WAY,78,KITTY CAT,70,HOT DOGS,100,PRETTY HOT DOG ATTENDANT,3,NORTH,100,SOUTH,100,EAST,100,WEST,100,UP,100,DOWN,100
1740 :'****DIRECTIONS****
1745 DATA NORTH  ,SOUTH  ,EAST  ,WEST  ,UP  ,DOWN
1750 :'
1755 DATAGO ,TAKE ,LOOK ,DROP ,WEAR ,GIVE ,RELEASE ,GUZZLE ,GET ,LIFT ,ROW ,PUT ,OPEN ,SHED ,JUMP ,START ,DIG ,TIE ,SCORE ,INVENTORY
1760 DATAWELL WORTH KEEPING,PROP. DE J.C.,LAST ENTRY-TREASURE HIGH   AND DRY IN THE SKY,INSCRIPTION,POOR AND STARVING WRETCH,SHIPS RAILING,WINCH,POINTY END OF SHIP,THE MISSING LINKS,THE BOAT STOPS HERE,POOP  WHAT ELSE,DUE TO INFLATION NOW DOLLARDECK
1765 DATANOT FOR SEWING,NO SMOKING,,DARK LIQUID,,JEWELS OF EVERY KIND,LOCK MECHANISM CONTAINING  THREE HOLES,LARGE BEAST WITH KNUCKLES DRAGGING ON THE GROUND AND A FACE OF WARTS AND PUSS,LET THERE BE LIGHT
1770 DATANOT TO BE USED AS A LIFE   PRESERVER,DARK HOLE,MFG. BY CRUTCH & CO.,SLOW BUT SURE,KEY FOR BOAT,SPADE & CO.,?????UNDER WATER
1775 DATAROLLED MAP,CAUTION MAY REDUCE YOUR SIZE,FEED US WE'RE NOT FUSSY,FOR THE ASCENT OF MAN,TEETH,LITTLE RED RENTED
1780 DATAROOM BEYOND,IN GOLD WE TRUST,A SPARK OF LIFE,FISH SWIMMING,SMALL WHITE COBS,HAY STUFFED IN OLD         CLOTHING,FOR TIEING,BUOYS WILL BE BUOYS,BROWN COW,RUSTY HINGES
1785 DATATREASURES REEDEEMED HERE---TYPE IN'SCORE' TO SEE HOW YOU'VE DONE,FOR NAPPING,FOOTPRINT,24K,5K,RED STONES,PRETTY BUT DEADLY,A REAL STEAL,BESSY'S,FRIENDS OF WILLARDS,KITTY CAT WITH WHITE STRIPE,WIENER IN A BUN,GORGEOUS ATTENDANT,,,,,,
1790 GOTO1340
1795 PRINT"HANDS TOO FULL MATE":RETURN
1800 CLS:PRINT@76,"PRODUCED ":PRINT@111,"BY":PRINT@139,"WAYNE WOOD":PRINT@206,"AND":PRINT@266,"GERALD CASEY":PRINT@361,"pirate/adventure"
1810 FORX=1TO5000:NEXTX:RETURN